apply from: configPath
apply from: "$scriptPath/android_app.gradle"
apply from: protobufNanoConfig
apply from: frameworkDependencies

android {
    namespace 'com.android.launcher3'

    defaultConfig {
        versionCode 29
        versionName "10.0"
    }

    flavorDimensions = ["app", "recents"]
    productFlavors {
        aosp {
            dimension "app"
        }

        withQuickstep {
            dimension "recents"
        }
    }

    sourceSets {
        main {
            res.srcDirs = ["$launcherCode/res"]
            java.srcDir "$launcherCode/src"
            java.srcDir "$launcherCode/src_plugins"
            java.srcDir "$launcherCode/src_build_config"
            manifest.srcFile "$launcherCode/AndroidManifest-common.xml"
            proto {
                srcDir "$launcherCode/protos/"
                srcDir "$launcherCode/proto_overrides/"
            }
        }

        aosp {
            java.srcDir "$launcherCode/src_flags"
            java.srcDir "$launcherCode/src_shortcuts_overrides"
            manifest.srcFile "$launcherCode/AndroidManifest.xml"
        }

        withQuickstep {
            java.srcDir "$launcherCode/quickstep/src"
            java.srcDir "$launcherCode/quickstep/recents_ui_overrides/src"
            res.srcDir "$launcherCode/quickstep/res"
            res.srcDir "$launcherCode/quickstep/recents_ui_overrides/res"
            manifest.srcFile "$launcherCode/quickstep/AndroidManifest.xml"
        }
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }
}

final String ANDROID_X_VERSION = '1.0.0'
dependencies {
    implementation "androidx.dynamicanimation:dynamicanimation:${ANDROID_X_VERSION}"
    implementation "androidx.recyclerview:recyclerview:${ANDROID_X_VERSION}"
    implementation "androidx.preference:preference:${ANDROID_X_VERSION}"
    implementation project(':1000_r47:IconLoader')
    implementation project(':1000_r47:LauncherProtosNano')
    implementation project(':1000_r47:SystemUI:PluginCoreLib')
    implementation project(':1000_r47:SystemUI:SystemUISharedLib')
}

protobuf {
    generateProtoTasks {
        all().each { task ->
            task.builtins {
                javanano {
                    option "java_package=launcher_log_extension.proto|com.android.launcher3.userevent.nano"
                    option "java_package=launcher_log.proto|com.android.launcher3.userevent.nano"
                    option "java_package=launcher_dump.proto|com.android.launcher3.model.nano"
                    option "enum_style=java"
                }
            }
        }
    }
}