apply from: configPath
apply from: "$scriptPath/android_app.gradle"
apply from: protobufNanoConfig
apply from: frameworkDependencies

android {
    namespace 'com.android.launcher3'

    defaultConfig {
        versionCode 28
        versionName "9.0"
    }

    flavorDimensions = ["app", "recents"]
    productFlavors {
        aosp {
            dimension "app"
        }

        quickstep {
            dimension "recents"
        }
    }

    sourceSets {
        main {
            res.srcDirs = ["$launcherCode/res"]
            java.srcDir "$launcherCode/src"
            java.srcDir "$launcherCode/src_flags"
            manifest.srcFile "$launcherCode/AndroidManifest-common.xml"
            proto {
                srcDir "$launcherCode/protos/"
                srcDir "$launcherCode/proto_overrides/"
            }
        }

        aospQuickstep {
            manifest.srcFile "$launcherCode/AndroidManifest.xml"
        }

        quickstep {
            res.srcDirs = ["$launcherCode/quickstep/res"]
            java.srcDirs = ["$launcherCode/quickstep/src"]
            manifest.srcFile "$launcherCode/quickstep/AndroidManifest.xml"
        }
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }
}

final String SUPPORT_LIBS_VERSION = '28.0.0'
dependencies {
    implementation "com.android.support:support-v4:${SUPPORT_LIBS_VERSION}"
    implementation "com.android.support:support-dynamic-animation:${SUPPORT_LIBS_VERSION}"
    implementation "com.android.support:recyclerview-v7:${SUPPORT_LIBS_VERSION}"

    implementation fileTree(dir: "$launcherCode/quickstep/libs", include: 'sysui_shared.jar')
}

protobuf {
    generateProtoTasks {
        all().each { task ->
            task.builtins {
                javanano {
                    option "java_package=launcher_log_extension.proto|com.android.launcher3.userevent.nano"
                    option "java_package=launcher_log.proto|com.android.launcher3.userevent.nano"
                    option "java_package=launcher_dump.proto|com.android.launcher3.model.nano"
                    option "enum_style=java"
                }
            }
        }
    }
}