AndroidLauncher3/1210_r27/app/build.gradle

apply from: configPath
apply from: "$scriptPath/android_app.gradle"
apply from: protobufConfig
apply from: frameworkDependencies
apply plugin: 'kotlin-android'

android {
    namespace 'com.android.launcher3'

    defaultConfig {
        versionCode 32
        versionName "12.1"
    }

    flavorDimensions = ["app", "recents"]
    productFlavors {
        aosp {
            dimension "app"
        }

        withQuickstep {
            dimension "recents"
        }
    }

    sourceSets {
        main {
            res.srcDirs = ["$launcherCode/res"]
            java.srcDir "$launcherCode/src"
            java.srcDir "$launcherCode/src_plugins"
            java.srcDir "$launcherCode/src_build_config"
            manifest.srcFile "$launcherCode/AndroidManifest-common.xml"
            proto {
                srcDir "$launcherCode/protos/"
            }
        }

        aosp {
            java.srcDir "$launcherCode/src_flags"
            java.srcDir "$launcherCode/src_shortcuts_overrides"
        }

        aospWithQuickstep {
            manifest.srcFile "$launcherCode/quickstep/AndroidManifest-launcher.xml"
        }

        withQuickstep {
            java.srcDir "$launcherCode/quickstep/src"
            java.srcDir "$launcherCode/quickstep/recents_ui_overrides/src"
            res.srcDir "$launcherCode/quickstep/res"
            res.srcDir "$launcherCode/quickstep/recents_ui_overrides/res"
            manifest.srcFile "$launcherCode/quickstep/AndroidManifest.xml"
            proto {
                srcDirs = ["$launcherCode/quickstep/protos_overrides"]
            }
        }
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }

    kotlinOptions {
        jvmTarget = "1.8"
    }
}

final String ANDROID_X_VERSION = '1.2.0'
dependencies {
    implementation "androidx.core:core:${ANDROID_X_VERSION}"
    implementation "androidx.fragment:fragment:${ANDROID_X_VERSION}"
    implementation "androidx.dynamicanimation:dynamicanimation:1.0.0"
    implementation "androidx.recyclerview:recyclerview:${ANDROID_X_VERSION}"
    implementation "androidx.preference:preference:${ANDROID_X_VERSION}"
    implementation "androidx.constraintlayout:constraintlayout:2.0.0"
    implementation "com.google.android.material:material:1.4.0"
    implementation "androidx.slice:slice-core:1.1.0-alpha02"
    implementation "androidx.slice:slice-builders:1.1.0-alpha02"
    implementation 'com.airbnb.android:lottie:3.3.0'
    implementation project(":$rootDirName:IconLoader")
    implementation project(":$rootDirName:SystemUI:PluginCoreLib")
    implementation project(":$rootDirName:SystemUI:SystemUISharedLib")
    implementation project(":$rootDirName:SystemUI:SysUiStatsLog")
    implementation project(":$rootDirName:WindowManager:Shell")
}