AndroidLauncher3/1300_r83/app/build.gradle

import java.nio.file.Paths

apply from: configPath
ext {
    codePath = Paths.get("$rootDir", "$rootDirName", "$launcherPath")
}
apply from: "$scriptPath/android_app.gradle"
apply from: protobufConfig
apply from: frameworkDependencies
apply plugin: 'kotlin-android'

android {
    namespace 'com.android.launcher3'

    defaultConfig {
        minSdk 33
        versionCode 330
        versionName "13.0"
    }

    flavorDimensions = ["app", "recents"]
    productFlavors {
        aosp {
            dimension "app"
        }

        withQuickstep {
            dimension "recents"
        }
    }

    sourceSets {
        main {
            res.srcDirs = ["$codePath/res"]
            java.srcDir "$codePath/src"
            java.srcDir "$codePath/src_plugins"
            java.srcDir "$codePath/src_build_config"
            java.srcDir "$codePath/tests/shared"
            manifest.srcFile "$codePath/AndroidManifest-common.xml"
            proto {
                srcDir "$codePath/protos/"
            }
        }

        aosp {
            java.srcDir "$codePath/src_flags"
            java.srcDir "$codePath/src_shortcuts_overrides"
        }

        aospWithQuickstep {
            manifest.srcFile "$codePath/quickstep/AndroidManifest-launcher.xml"
        }

        withQuickstep {
            java.srcDir "$codePath/quickstep/src"
            java.srcDir "$codePath/quickstep/recents_ui_overrides/src"
            res.srcDir "$codePath/quickstep/res"
            res.srcDir "$codePath/quickstep/recents_ui_overrides/res"
            manifest.srcFile "$codePath/quickstep/AndroidManifest.xml"
            proto {
                srcDirs = ["$codePath/quickstep/protos_overrides"]
            }
        }
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }

    kotlinOptions {
        jvmTarget = "1.8"
    }
}

final String ANDROID_X_VERSION = '1.2.0'
dependencies {
    implementation "androidx.core:core:${ANDROID_X_VERSION}"
    implementation "androidx.fragment:fragment:${ANDROID_X_VERSION}"
    implementation "androidx.dynamicanimation:dynamicanimation:1.0.0"
    implementation "androidx.recyclerview:recyclerview:${ANDROID_X_VERSION}"
    implementation "androidx.preference:preference:${ANDROID_X_VERSION}"
    implementation "androidx.constraintlayout:constraintlayout:2.0.0"
    implementation "com.google.android.material:material:1.4.0"
    implementation "androidx.slice:slice-core:1.1.0-alpha02"
    implementation "androidx.slice:slice-builders:1.1.0-alpha02"
    implementation 'com.airbnb.android:lottie:3.3.0'
    implementation project(":$rootDirName:IconLoader")
    implementation project(":$rootDirName:SystemUI:PluginCoreLib")
    implementation project(":$rootDirName:SystemUI:SystemUISharedLib")
    implementation project(":$rootDirName:SystemUI:SystemUIAnimationLib")
    implementation project(":$rootDirName:SystemUI:SystemUIUnfoldLib")
    implementation project(":$rootDirName:SystemUI:SysUiStatsLog")
    implementation project(":$rootDirName:SystemUI:ViewCapture")
    implementation project(":$rootDirName:WindowManager:Shell")
}