apply from: rootProject.file('gradle/build_library.gradle')
apply plugin: 'kotlin-android'
apply plugin: 'kotlin-android-extensions'
apply plugin: 'com.kezong.fat-aar'


android {

    def miniAppPluginConfig = rootProject.ext.miniAppPluginConfig
    defaultConfig {
        buildConfigField "String", "PLUGIN_ID", "\"$miniAppPluginConfig.pluginId\""

    }
    sourceSets {
        main {
            jniLibs.srcDirs = ["libs"]
        }
    }
}


repositories {
    flatDir {
        dirs 'libs'
    }
    maven { url "https://maven.oa.com/nexus/content/repositories/google-maven/" }
    maven { url 'https://maven.aliyun.com/repository/gradle-plugin' } //gradle-plugin
    maven { url 'https://maven.aliyun.com/repository/google' } //google
    maven { url 'https://maven.aliyun.com/repository/public' } //public
    maven { url 'https://maven.aliyun.com/repository/jcenter' } //jcenter
}


def saaaSDKVersionDepend = rootProject.ext.saaaSDKVersionDepend

def libsDir = file("./libs")

if (!file("$libsDir/com/tencent/luggage/wxa-standalone-open-runtime-SaaA-plugin-sdk/${saaaSDKVersionDepend}").exists()) {
    libsDir.mkdir()

    apply plugin: 'de.undercouch.download'

    def zipFileName = "wxa-standalone-open-runtime-SaaA-sdk-all-${saaaSDKVersionDepend}.zip"
    download.run {
        src "https://dldir1.qq.com/WechatWebDev/donut/android/pluginsdk/${zipFileName}"
        dest libsDir
    }
    def zipFilePath = "$libsDir/$zipFileName"
    copy {
        def subDir = 'localAar'
        from {
            zipTree(zipFilePath).matching { include "$subDir/**" }
        }
        into libsDir
        eachFile { fcp ->
            fcp.path = fcp.path.replaceFirst("^$subDir", '')
        }
        includeEmptyDirs false
    }
    file(zipFilePath).delete()
}

fataar {
    transitive = true
}

dependencies {
    implementation "androidx.exifinterface:exifinterface:1.1.0"

    implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk7:$kotlin_version"
    implementation "org.jetbrains.kotlin:kotlin-stdlib:$kotlin_version"

    api "androidx.constraintlayout:constraintlayout:1.1.3"

    api 'com.google.android.material:material:1.0.0'

    compileOnly("com.tencent.luggage:wxa-standalone-open-runtime-SaaA-plugin-sdk:$saaaSDKVersionDepend") {}


    implementation('io.github.jeremyliao:live-event-bus-x:1.8.0')
    implementation('io.github.FailedToRead:intermodal-release:1.0.1')
    implementation('io.github.FailedToRead:oaid_sdk_1.0.25:1.0.1')
    implementation('io.github.FailedToRead:huawei-maven-release:1.0.2')


    implementation 'com.squareup.okhttp3:okhttp:4.2.0'
    implementation 'com.google.code.gson:gson:2.8.7'




//    implementation 'com.alipay.sdk:alipaysdk-android:+@aar'

//    implementation project(path: ':LocalRepo:intermodal-release', configuration: 'default')
//    implementation project(path: ':LocalRepo:oaid_sdk', configuration: 'default')
}

clearDuplicatedJniLibs([
        '**/jni/x86/**',
        '**/jni/x86_64/**',
        '**/jni/armeabi/**',
        '**/jni/**/libc++_shared.so'
])

project.ext.pomDeps = [
        'io.github.jeremyliao:live-event-bus-x'    : '1.8.0',
        'io.github.FailedToRead:intermodal-release': '1.0.1',
        'io.github.FailedToRead:oaid_sdk_1.0.25'   : '1.0.1',
        'io.github.FailedToRead:huawei-maven-release'   : '1.0.2'
]